Arc Forum | fork() in Arc

Arc Forum

fork() in Arc

7 points by eds 5863 days ago | 20 comments

I am attempting to mimic a unix fork() in Arc. So far I have tried calling a continuation from inside a new thread, but that failed:

  arc> (def fork ()
         (ccc
           (fn (c)
             (thread (c nil)))))
  arc> (if (fork)
           (prn "parent")
           (prn "child"))
  parent
  "parent"
  arc> continuation application: attempted to cross a continuation barrier

Am I missing something here, or is it simply not possible to call a continuation from inside another thread?

If I can't call a continuation inside another thread, is there a way to call fork() from inside mzscheme? (I've heard that 'subprocess calls fork(), but I don't know if that is really what I want or not, and I can't find any documentation on it.)

Any other suggestions as to how I could simulate fork would be appreciated.

4 points by kens 5862 days ago | link

I'll step back and ask what you're trying to do with fork. If you do a genuine fork, you'll end up with two mzscheme interpreters running, which may or may not be what you want.

If you're looking to exec a new process, subprocess will do that; it's documented at http://download.plt-scheme.org/doc/mzscheme/mzscheme-Z-H-15....

You asked about doing a wait; you pass the child's pid to wait.

Returning to your original example, Mzscheme supports calling continuations from another thread, as documented at http://download.plt-scheme.org/doc/mzscheme/mzscheme-Z-H-6.h... That page also describes the continuation barriers. The issue is that you can't have a new thread call a continuation in the main thread, since then you'd have two main REPL threads, which doesn't make sense.

What you need to do is run your example in yet another thread:

  arc> (def doit () (if (fork) (prn "Parent") (prn "Child")))
  arc> (thread (doit))

Then you'll get the result you're expecting.

-----

1 point by eds 5860 days ago | link

Now I have two questions about threads:

Is there a way to wait for a thread to end, other than something like

  (let th (thread (sleep 1))
    (until (dead th))
    (pr 'done))

Also, is there a way to make a thread-local variable so threads don't all try to update the same global variable? For example

  (= pid 0)
  
  (def test ()
    (let parent? (fork)
      (= pid (+ (* pid 2) (if parent? 0 1)))))
  
  (thread
    (test)
    (test)
    (test)
    (prn pid))

prints 0, 1, 12, 25, 102, 205, 822, 1645, which much larger than the expected 1, 2, 3, 4, 5, 6, 7, 8 because all the threads update the same global variable

-----

2 points by almkglor 5860 days ago | link

I recently added thread-local variables to Anarki (last week or week before last, maybe). To use:

  (= foo (thread-local))
  (foo) ; read the variable
  (= (foo) 42) ; write the variable

Also, I've added semaphores to Anarki. If you want to wait on another thread:

  (let s (sema)
    ; thread you're waiting on
    (thread
      (sleep 1)
      (sema-post s))
    ; monitoring thread
    (sync s)
    (pr 'done))

As mentioned, Anarki only ^^

-----

2 points by eds 5859 days ago | link

Looking at 'sync documentation, it would seem that you can also just call 'sync on a thread to wait for it to end.

  (let th
    ; thread you're waiting on
    (thread
      (sleep 1))
    ; monitoring thread
    (sync th)
    (pr 'done))

-----

1 point by eds 5859 days ago | link

Thanks, that is exactly what I wanted. Although it might be nice to have a macro wrapper around 'thread-local for initializing variables

  (w/uniq void
    (mac w/thread-local (var (o val void))
      (if (is val void)
	  `(= ,var (thread-local))
	  `(do (= ,var (thread-local))
	       (= (,var) ,val)))))

then you could do

  (w/thread-local foo 0)

instead of the two step initialization

  (= foo (thread-local))
  (= (foo) 0)

-----

1 point by eds 5860 days ago | link

Thanks for the information on continuations and threads. Your suggestion worked perfectly for me.

And if you have to know, I am trying to port a program entered in the 5th annual Obfuscated Perl Contest (http://perl.plover.com/obfuscated/). It was originally implemented using fork(), but I was experimenting with using continuations and threads just to see if it would work.

-----

2 points by kens 5859 days ago | link

I took a look at the Perl program. Just a warning: Arc doesn't have real pipes, so if you try to synchronize on pipes like the Arc program, you're in for trouble. Also, if you implement real forks and fork 32 mzscheme interpreters in parallel, you better have a bigger computer than mine :-)

-----

2 points by almkglor 5859 days ago | link

I also added pipes to Anarki.

  (let (input-end output-end) (pipe)
    (...do what you will...))

-----

2 points by stefano 5863 days ago | link

On Anarki, you could try using:

  (require "ffi.arc")
  
  (w/ffi "libc.so"
    (cdef fork "fork" cint ()))

Now you should have imported fork.

-----

2 points by eds 5862 days ago | link

Thanks for your suggestion.

I do have one question about loading libc. Since the system doesn't automatically find libc.so for you, you need to name the path explicitly. What worked for me was

  (w/ffi "/lib/libc.so.6"
    (cdef fork "fork" cint ()))

but I don't really know if this is the right way to do it. Is there a better way?

-----

2 points by elibarzilay 5862 days ago | link

The underlying foreign implementation is looking for the library. The problem is that /usr/lib/libc.so is not the library and dlopen() does not know how to handle this.

A better alternative with mzscheme's foreign interface is to use `#f' for the library -- that treats the mzscheme binary as the library to open (which includes the usual libc stuff.)

-----

1 point by sacado 5862 days ago | link

Interesting. Should be added to ffi.arc...

-----

2 points by eds 5862 days ago | link

Yeah, because currently if you attempt

  (w/ffi #f
    (cdef cfork "fork" cint ()))

arc will convert #f to nil, which mzcheme thinks is an unbound variable. There are work-arounds, like

  (w/ffi (read "#f")
    (cdef cfork "fork" cint ()))

but this is rather ugly.

-----

1 point by eds 5862 days ago | link

Also, I think I need to use wait() to wait for a child process to terminate, but I am somewhat at a loss as to how to accomplish this, since the manual says it takes an int pointer... Again, any help would be appreciate.

-----

2 points by stefano 5862 days ago | link

Try:

  (cdef _wait "wait" cint (cptr))

  (def wait (i)
    (let pi (cmalloc 4)
      (cpset pi cint i)
      (_wait pi)))

This creates a pointer, assign it a value and returns the value returned by _wait.

-----

1 point by eds 5857 days ago | link

Also, in your malloc() example, don't you have to explicitly free the memory afterwards? MzScheme's GC doesn't deal with memory explicitly allocated from C, does it? (I know the example itself uses only a tiny amount of memory, but still...)

-----

1 point by sacado 5857 days ago | link

Yes and no. I think mzscheme's GC can handle it without explicitly calling free at the right time, but you have to register a "finalizer" function to do so. That function will be called when the GC collects the object.

It does not know the size of malloced objects however, so be careful (no pb there, but if you allocate something very big, mzscheme will only see a new reference and will not necessarily call GC when you will actually lack memory).

-----

3 points by stefano 5857 days ago | link

If you alloc memory with cmalloc mzscheme will automatically delete it for you. Try

  (def infinite ()
    (cmalloc 4)
    (infinite))

  (infinite)

You shouldn't run out of memory. If you do, then I'm wrong.

-----

1 point by eds 5860 days ago | link

Just wondering: is there a way to malloc(sizeof(int)) from inside Arc instead of hard coding the size of an int?

-----

2 points by stefano 5860 days ago | link

You can make a C function like this:

  int size_of_int ()
  {
    return sizeof(int);
  }

and import it. I've followed this route while writing gtk.arc, but probably there's a better way to do it.

-----